Mike Gerwitz

Activist for User Freedom

aboutsummaryrefslogtreecommitdiffstats
blob: 469603d6e17caf21bfb0f3def4a8957b21510fe6 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
<?xml version="1.0" encoding="ISO-8859-1"?>
<!--
  Operations on paths
-->
<xsl:stylesheet version="1.0"
  xmlns="http://www.w3.org/1999/xhtml"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:preproc="http://www.lovullo.com/rater/preproc">


<xsl:template name="preproc:get-path">
  <xsl:param name="path" />
  <xsl:param name="prev" select="''" />

  <xsl:variable name="first" select="substring-before( $path, '/' )" />
  <xsl:variable name="rest" select="substring-after( $path, '/' )" />

  <xsl:choose>
    <!-- if there's no $first, then there is no path separator, in which case
         we're done; if there's no rest, then there is a path separator, but it
         resulted in an empty string, meanaing that it ends in a path
         separator, in which case we are also done -->
    <xsl:when test="not( $first ) or not( $rest )">
      <!-- no more path separators; we're done -->
      <xsl:value-of select="$prev" />
    </xsl:when>

    <!-- keep recursing -->
    <xsl:otherwise>
      <xsl:call-template name="preproc:get-path">
        <xsl:with-param name="path" select="$rest" />
        <xsl:with-param name="prev">
          <xsl:if test="not( $prev = '' )">
            <xsl:value-of select="concat( $prev, '/' )" />
          </xsl:if>

          <xsl:value-of select="$first" />
        </xsl:with-param>
      </xsl:call-template>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>


<!-- FIXME: duplicate code with above -->
<xsl:template name="preproc:get-basename">
  <xsl:param name="path" />
  <xsl:param name="prev" select="''" />

  <xsl:variable name="first" select="substring-before( $path, '/' )" />
  <xsl:variable name="rest" select="substring-after( $path, '/' )" />

  <xsl:choose>
    <!-- if there's no $first, then there is no path separator, in which case
         we're done; if there's no rest, then there is a path separator, but it
         resulted in an empty string, meanaing that it ends in a path
         separator, in which case we are also done -->
    <xsl:when test="not( $first ) or not( $rest )">
      <!-- no more path separators; we're done -->
      <xsl:value-of select="$path" />
    </xsl:when>

    <!-- keep recursing -->
    <xsl:otherwise>
      <xsl:call-template name="preproc:get-basename">
        <xsl:with-param name="path" select="$rest" />
        <xsl:with-param name="prev">
          <xsl:if test="not( $prev = '' )">
            <xsl:value-of select="concat( $prev, '/' )" />
          </xsl:if>

          <xsl:value-of select="$first" />
        </xsl:with-param>
      </xsl:call-template>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>


<xsl:template name="preproc:resolv-path">
  <xsl:param name="path" />

  <!-- in order: strip //, process ../, strip ./ -->
  <xsl:call-template name="preproc:strip-sdot-path">
    <xsl:with-param name="path">
      <xsl:call-template name="preproc:resolv-rel-path">
        <xsl:with-param name="path">
          <xsl:call-template name="preproc:strip-extra-path">
            <xsl:with-param name="path" select="$path" />
          </xsl:call-template>
        </xsl:with-param>
      </xsl:call-template>
    </xsl:with-param>
  </xsl:call-template>
</xsl:template>


<!-- XXX: warning, this won't like 'foo../' -->
<xsl:template name="preproc:resolv-rel-path">
  <xsl:param name="path" />

  <!-- relative paths -->
  <xsl:variable name="before" select="substring-before( $path, '../' )" />
  <xsl:variable name="after" select="substring-after( $path, '../' )" />

  <xsl:choose>
    <xsl:when test="$before">
      <xsl:call-template name="preproc:resolv-rel-path">
        <xsl:with-param name="path">
          <!-- remove the last directory before the ../ -->
          <xsl:variable name="before-path">
            <xsl:call-template name="preproc:get-path">
              <xsl:with-param name="path" select="$before" />
            </xsl:call-template>
          </xsl:variable>

          <xsl:value-of select="$before-path" />

          <!-- the above get-path call will strip the trailing slash -->
          <xsl:if test="not( $before-path = '' ) and not( $after = '' )">
            <xsl:text>/</xsl:text>
          </xsl:if>

          <xsl:value-of select="$after" />
        </xsl:with-param>
      </xsl:call-template>
    </xsl:when>


    <!-- if there's no $before but there is an $after, then we must begin with
         '../', which we can do nothing with; output it and continue processing
         the remainder of the path -->
    <xsl:when test="$after">
      <xsl:text>../</xsl:text>

      <xsl:call-template name="preproc:resolv-rel-path">
        <xsl:with-param name="path" select="$after" />
      </xsl:call-template>
    </xsl:when>


    <!-- no relative paths remaining -->
    <xsl:otherwise>
      <xsl:value-of select="$path" />
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>


<xsl:template name="preproc:strip-sdot-path">
  <xsl:param name="path" />

  <xsl:choose>
    <!-- the only time this should be called with an unresolved relative path
         is if it begins with one, in which case we'll simply output it and
         continue processing without it -->
    <xsl:when test="starts-with( $path, '../' )">
      <xsl:text>../</xsl:text>

      <!-- continue processing without it -->
      <xsl:call-template name="preproc:strip-sdot-path">
        <xsl:with-param name="path" select="substring-after( $path, '../' )" />
      </xsl:call-template>
    </xsl:when>


    <!-- path is safe for processing -->
    <xsl:otherwise>
      <xsl:variable name="a" select="substring-before( $path, './' )" />
      <xsl:variable name="b" select="substring-after( $path, './' )" />


      <xsl:choose>
        <!-- if we found one, recurse -->
        <xsl:when test="$a or $b">
          <xsl:call-template name="preproc:strip-sdot-path">
            <xsl:with-param name="path">
              <xsl:value-of select="$a" />

              <xsl:if test="$a and $b">
                <xsl:text>/</xsl:text>
              </xsl:if>

              <xsl:value-of select="$b" />
            </xsl:with-param>
          </xsl:call-template>
        </xsl:when>


        <!-- done -->
        <xsl:otherwise>
          <xsl:value-of select="$path" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>


<xsl:template name="preproc:strip-extra-path">
  <xsl:param name="path" />

  <xsl:variable name="a" select="substring-before( $path, '//' )" />
  <xsl:variable name="b" select="substring-after( $path, '//' )" />


  <xsl:choose>
    <!-- if we found one, recurse -->
    <xsl:when test="$a or $b">
      <xsl:call-template name="preproc:strip-extra-path">
        <xsl:with-param name="path">
          <xsl:value-of select="$a" />

          <xsl:if test="$a and $b">
            <xsl:text>/</xsl:text>
          </xsl:if>

          <xsl:value-of select="$b" />
        </xsl:with-param>
      </xsl:call-template>
    </xsl:when>

    <!-- we're done! -->
    <xsl:otherwise>
      <xsl:value-of select="$path" />
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

</xsl:stylesheet>