Mike Gerwitz

Activist for User Freedom

aboutsummaryrefslogtreecommitdiffstats
blob: 3bcbc7b454f89ec74b02378b0c9da25ee2e5f1e2 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
#!/usr/bin/awk -f
#
# Compiles a "magic" CSV file into a normal CSV
#
#   Copyright (C) 2016 LoVullo Associates, Inc.
#
#   This program is free software: you can redistribute it and/or modify
#   it under the terms of the GNU General Public License as published by
#   the Free Software Foundation, either version 3 of the License, or
#   (at your option) any later version.
#
#   This program is distributed in the hope that it will be useful,
#   but WITHOUT ANY WARRANTY; without even the implied warranty of
#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#   GNU General Public License for more details.
#
#   You should have received a copy of the GNU General Public License
#   along with this program.  If not, see <http://www.gnu.org/licenses/>.
#
# "Magic" CSVs simply exist to make life easier: they permit comments, blank
# lines, variables, sub-delimiter expansion, and any number of ranges per line.
# Ranges will be expanded in every combination, making rate tables highly
# maintainable.
#
# Variables are also supported when defined using :var=val. Variables may
# expand into ranges, 'cause they're awesome. Multiple variables may be
# delimited by semi-colons, as may multiple values.
#
# For example:
#   :foo=1--3
#   $foo;7;9--10:$foo, 5--10
#
# Would generate:
#   1, 5
#   1, 6
#   ...
#   5, 10
#   2, 5
#   ...
#   9, 5
#   ...
#   1, 5
#   1, 6
#   ...
##


function rangeout( i, m, j, me, orig )
{
  if ( i > NF )
  {
    print
    return
  }

  orig = $i

  # check first for delimiters
  if ( match( $i, /^([^;]+);(.*)$/, m ) )
  {
    # give it a shot with the first value
    $i = m[1]
    rangeout( i )

    # strip off the first value and process with following value(s)
    $i = m[2]
    rangeout( i )

    # we've delegated; we're done
    $i = orig
    return
  }

  # attempt to parse variable (may expand into a range)
  if ( match( $i, /^\$([a-zA-Z_-]+)$/, m ) )
  {
    $i = vars[ m[1] ];
  }

  # parse range
  if ( match( $i, /^([0-9]+)--([0-9]+)$/, m ) )
  {
    j  = m[1]
    me = m[2]
    do
    {
      $i = j
      rangeout( i + 1 )
    } while ( j++ < me )
  }
  else
  {
    rangeout( i + 1 );
  }

  # restore to original value
  $i = orig
}


BEGIN {
  # we're parsing CSVs
  FS = " *, *"
  OFS = ","
}


# skip all lines that begin with `#', which denotes a comment, or are empty
/^#|^$/ { next; }

# lines that begin with a colon are variable definitions
/^:/ {
  match( $0, /^:([a-zA-Z_-]+)=(.*?)$/, m )
  vars[ m[1] ] = m[2]
  next
}

# lines containing ranges (denoted by `--', the en dash, which is a typesetting
# convetion for ranges), sub-delimiters, or variables must be expanded
/--|;|\$[a-zA-Z_-]/ { rangeout( 1 ); next; }

# all other lines are normal; simply output them verbatim
{
  # this assignment will ensure that awk processes the output, ensuring that
  # extra spaces between commas are stripped
  $1=$1
  print
}